To return a node, list it in the RETURN statement.

Query. 

MATCH (n { name: "B" })
RETURN n

The example will return the node.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (n {name: "B"}) return n

To return a relationship, just include it in the RETURN list.

Query. 

MATCH (n { name: "A" })-[r:KNOWS]->(c)
RETURN r

The relationship is returned by the example.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (n {name: "A"})-[r:KNOWS]->(c) return r

To return a property, use the dot separator, like this:

Query. 

MATCH (n { name: "A" })
RETURN n.name

The value of the property name gets returned.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (n {name: "A"}) return n.name

When you want to return all nodes, relationships and paths found in a query, you can use the * symbol.

Query. 

MATCH p=(a { name: "A" })-[r]->(b)
RETURN *

This returns the two nodes, the relationship and the path used in the query.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match p=(a {name: "A"})-[r]->(b) return *

To introduce a placeholder that is made up of characters that are outside of the english alphabet, you can use the ` to enclose the identifier, like this:

Query. 

MATCH (`This isn't a common identifier`)
WHERE `This isn't a common identifier`.name='A'
RETURN `This isn't a common identifier`.happy

The node with name "A" is returned

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (`This isn't a common identifier`) where `This isn't a common identifier`.name='A' return `This isn't a common identifier`.happy

If the name of the column should be different from the expression used, you can rename it by using AS <new name>.

Query. 

MATCH (a { name: "A" })
RETURN a.age AS SomethingTotallyDifferent

Returns the age property of a node, but renames the column.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (a {name: "A"}) return a.age AS SomethingTotallyDifferent

If a property might or might not be there, you can still select it as usual. It will be treated as NULL if it is missing

Query. 

MATCH (n)
RETURN n.age

This example returns the age when the node has that property, or null if the property is not there.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (n) return n.age

Any expression can be used as a return item — literals, predicates, properties, functions, and everything else.

Query. 

MATCH (a { name: "A" })
RETURN a.age > 30, "I'm a literal",(a)-->()

Returns a predicate, a literal and function call with a pattern expression parameter.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (a {name: "A"}) return a.age > 30, "I'm a literal", (a)-->()

DISTINCT retrieves only unique rows depending on the columns that have been selected to output.

Query. 

MATCH (a { name: "A" })-->(b)
RETURN DISTINCT b

The node named B is returned by the query, but only once.

Try this query live. create (_0 {`age`:55, `happy`:"Yes!", `name`:"A"}) create (_1 {`name`:"B"}) create _0-[:`KNOWS`]->_1 create _0-[:`BLOCKS`]->_1 match (a {name: "A"})-->(b) return distinct b